10.4. Создание специальных символов и анимации

Что делать, если вы хотите отобразить информацию, которую нельзя выразить с помощью обычных символов? Например, требуется вывести греческую букву, знак градуса или индикатор загрузки. К счастью, библиотека LiquidCrystal поддерживает создание пользовательских символов, которые могут быть отображены на дисплее. В следующем примере мы воспользуемся этой возможностью, чтобы реализовать движущийся значок, перемещающийся по экрану. А после этого создадим знак градуса для отображения измеряемой температуры.

Создавать пользовательские символы просто. Если внимательно посмотреть на ЖК-дисплей, то видно, что каждое знакоместо состоит из матрицы 5х8 пикселов.

Чтобы создать пользовательский символ, нужно определить значение каждой из этих точек и отправить соответствующую информацию на дисплей. Попробуем создать несколько символов, которые будут заполнять вторую строку дисплея анимированным прогресс-баром. Поскольку ширина каждого символа составляет 5 пикселов, для заполнения всей строки потребуются 5 пользовательских символов: первый с одним заполненным столбцом, второй с двумя столбцами и т. д.

В начале программы создаем для каждого символа массив байтов, в котором включенным пикселам будут соответствовать единицы, а выключенным - нули. Для первого символа (заполняющего 20% от ширины строки) массив выглядит следующим образом:

byte p20[8] = {

B10000,

- 209 -

B10000,

B10000,

B10000,

B10000,

B10000,

B10000,

B10000,

};

Я назвал этот массив p2О, чтобы показать, что этот символ заполняет 20% пространства. В функции setup() вызываем библиотечную функцию createChar(), чтобы назначить данному массиву идентификатор ID пользовательского символа.

Пользовательские символы имеют ID от 0 до 7, вы можете в общей сложности сформировать восемь таких символов. Определим массив p20 как пользовательский символ с ID=0: lcd.createChar (0, p20);

Для отображения пользовательского символа на дисплее поместите курсор в нужное место и выполните команду lcd.write ( (byte) 0);

Добавьте остальные пользовательские символы и с помощью двух вложенных циклов в основном цикле программы loop() обновляйте прогресс-бар. Код данной программы приведен в листинге 10.2.

Листинг 10.2. Код прогресс-бара на экране дисплея - LCD_progress_bar.ino

// Прогресс-бар на ЖК-дисплее

// Подключение библиотеки LiquidCrystal

#include <LiquidCrystal.h>

// Инициализация экземпляра библиотеки LiquidCrystal

LiquidCrystal lcd(2, 3, 4, 5, 6, 7);

// Создание массивов для символов прогресс-бара

byte p20[8] = {

B10000,

B10000,

B10000,

B10000,

B10000,

B10000,

B10000,

B10000,

};

byte p40[8] = {

B11000,

B11000,

- 210 -

B11000,

B11000,

B11000,

B11000,

B11000,

B11000,

};

byte p60[8] = {

B11100,

B11100,

B11100,

B11100,

B11100,

B11100,

B11100,

B11100,

};

byte p80 [8] = {

B11110,

B11110,

B11110,

B11110,

B11110,

B11110,

B11110,

B11110,

};

byte p100[8] = {

B11111,

B11111,

B11111,

B11111,

B11111,

B11111,

B11111,

B11111,

};

void setup()

{

// Настройка экземпляра дисплея - число столбцов и строк:

lcd.begin(16, 2);

// Вывод текста на ЖК-дисплей

lcd.print("Jeremy's Display");

// Определение пользовательских символов

lcd.createChar(0,p20);

- 211 -

lcd.createChar(1,p40);

lcd.createChar(2,p60);

lcd.createChar(3,p80);

lcd.createChar(4,p100);

}

void loop()

{

// Курсор в начало второй строки

lcd.setCursor(0,1);

// Очистка второй строки

// 16 пробелов

lcd.print(" ");

// Перебор каждого символа на второй строке

for (int i = 0; i<16; i++)

{

// Перебор каждого значения (p20 - p100)

for (int j=0; j<5; j++)

{

lcd.setCursor(i, 1);// Столбец установки курсора

lcd. write (j);// Вывод символа

delay(100);// Задержка

}

}

}

В начале каждого цикла во все 16 позиций второй строки выводится символ пробела ( строка очищается). Внешний цикл for() перебирает все 16 знакомест строки.

Во внутреннем цикле for() в каждое знакоместо с задержкой выводится увеличивающийся пользовательский символ прогресс-бара.

ПРИМЕЧАНИЕ

Для просмотра видеоклипа, демонстрирующего отображение прогресс-бара на ЖК-дисплее, посетите страницу http://www.exploringarduino.com/content/ch10. Этот видеоклип доступен также на сайте издательства Wiley.